1cePeak

智能家居|手把手教你自制一款远程开关灯装置

智能家居|手把手教你自制一款远程开关灯装置
2022-11-29 · 6 min read
IOT Life

冬天到了,因为房东没有在床头安装房间灯的开关,所以导致我每次都要艰难地掀开温暖的被窝下床去关灯,这样让我萌生了做一个智能开关灯的装置,要考虑的问题有:

  1. 远程开关灯
  2. 供电
  3. 成本

经过一番探索后发现,使用如下硬件配置(仅需18RMB💰):

  • ESP8266 WiFi模块
  • SG90舵机
  • 杜邦线
  • USB数据线
  • 电源



软件:
Arduino IDE

大家可以根据自己的操作系统在Arduino官网下载对应的版本
https://www.arduino.cc/en/software
接下来打开Arduino IDE,首先需要在菜单栏中点击首选项并添加开发版管理器的网址http://arduino.esp8266.com/stable/package_esp8266com_index.json

再点击菜单栏中的工具-开发板-开发板管理器-安装ESP8266开发版对应的库文件

配置好环境以后就可以接线并运行代码了,在接线之前需要了解舵机三根线的作用:

  • 橙色信号线(PWM)
  • 红色电源正极(VV)
  • 棕色电源负极(GND)

将舵机和ESP8266开发板接线:

然后使用USB线连接电脑,在Arduino中可以看到该开发板连接成功的信息,编写可以控制舵机的代码:

#include <ESP8266WiFi.h>        //  本程序使用 ESP8266WiFi库
#include <ESP8266WiFiMulti.h>   //  ESP8266WiFiMulti库
#include <ESP8266WebServer.h>   //  ESP8266WebServer库
#include <Servo.h>              //  引入伺服电机驱动库

Servo Servo1; //实例化一个对象
ESP8266WiFiMulti wifiMulti;     // 建立ESP8266WiFiMulti对象,对象名称是 'wifiMulti'
ESP8266WebServer esp8266_server(80);// 建立网络服务器对象,该对象用于响应HTTP请求。监听端口(80)
 
void setup(void){
  Serial.begin(9600);   // 启动串口通讯
  Servo1.attach(D4); // 给伺服电机绑定一个数字引脚
 
  wifiMulti.addAP("WiFi名称", "WiFi密码"); // 将需要连接的一系列WiFi ID和密码输入这里
  //wifiMulti.addAP("ssid_from_AP_2", "your_password_for_AP_2"); // ESP8266-NodeMCU再启动后会扫描当前网络
  //wifiMulti.addAP("ssid_from_AP_3", "your_password_for_AP_3"); // 环境查找是否有这里列出的WiFi ID。如果有
  Serial.println("Connecting ...");                            // 则尝试使用此处存储的密码进行连接。
  
  int i = 0;                                 
  while (wifiMulti.run() != WL_CONNECTED) {  // 此处的wifiMulti.run()是重点。通过wifiMulti.run(),NodeMCU将会在当前
    delay(1000);                             // 环境中搜索addAP函数所存储的WiFi。如果搜到多个存储的WiFi那么NodeMCU
    Serial.print(i++); Serial.print(' ');    // 将会连接信号最强的那一个WiFi信号。
  }                                          // 一旦连接WiFI成功,wifiMulti.run()将会返回“WL_CONNECTED”。这也是
                                             // 此处while循环判断是否跳出循环的条件。
  
  // WiFi连接成功后将通过串口监视器输出连接成功信息 
  Serial.println('\n');
  Serial.print("Connected to 123");
  Serial.println(WiFi.SSID());              // 通过串口监视器输出连接的WiFi名称
  Serial.print("IP address:\t");
  Serial.println(WiFi.localIP());           // 通过串口监视器输出ESP8266-NodeMCU的IP
 
  esp8266_server.begin();                           // 启动网站服务
  esp8266_server.on("/", HTTP_GET, handleRoot);     // 设置服务器根目录即'/'的函数'handleRoot'
  esp8266_server.on("/openLED", HTTP_GET, openLED);  // 设置处理LED控制请求的函数'handleLED'
  esp8266_server.on("/closeLED",HTTP_GET, closeLED);
  esp8266_server.onNotFound(handleNotFound);        // 设置处理404情况的函数'handleNotFound'
  Serial.println("HTTP esp8266_server started");//  告知用户ESP8266网络服务功能已经启动
}
 
void loop(void){
 // Serial.println(digitalRead(D8));
  delay(100);
  esp8266_server.handleClient();                     // 检查http服务器访问
}
 

void handleRoot() {       
  //esp8266_server.send(200, "text/html", "<form action=\"/LED\" method=\"GET\"><input type=\"submit\" value=\"Toggle LED\"></form>");
  esp8266_server.send(200, "text/html","hello world");
}
 
//处理LED控制请求的函数'handleLED'
void openLED() {                          
  
  Serial.println("[+] The LED is open!");
  Servo1.write(0);
  delay(500);                                         // 保持舵机动力臂水平
  Servo1.write(90);
  esp8266_server.sendHeader("Location","/");          // 跳转回页面根目录
  esp8266_server.send(303);                           // 发送Http相应代码303 跳转  
}
 void closeLED() {                          
  
  Serial.println("[+] The LED is close!");
  Servo1.write(180);
  delay(500);                                         // 保持舵机动力臂水平
  Servo1.write(90);
  esp8266_server.sendHeader("Location","/");          // 跳转回页面根目录
  esp8266_server.send(303);                           // 发送Http相应代码303 跳转  
}
// 设置处理404情况的函数'handleNotFound'
void handleNotFound(){
  esp8266_server.send(404, "text/plain", "404: Not found"); // 发送 HTTP 状态 404 (未找到页面) 并向浏览器发送文字 "404: Not found"
}

这段代码实现了什么呢?实际上开了一个HTTP的服务,当接收到openLED的请求后,控制舵机旋转一定的角度,接收到closeLED的请求同理。然后运行这段代码

本地编译成功

最后需要将程序烧录进ESP8266开发板中,在烧录之前需要在菜单栏中选择工具-端口-点击开发板所连接的端口,否则会失败。

然后点击上传按钮,等待烧录完成。

在烧录的过程中可以看到指示灯在闪烁,当烧录完成以后可以看到ESP8266开发板指示灯常亮,这个时候就大功告成了!

那么开发板的IP是什么呢?可以在烧录过程中打开Arduino中的串口监视器来查看分配到的IP,也可以打开路由器的管理页面查看已连接的设备信息,hack一点的方法就是扫描当前C段下的网络😅
为了更好的固定舵机和开发板,可以使用热熔胶枪等设备将其固定在开关旁边,希望房东不要打我嘿嘿🤤
效果如图所示:

那么如何控制舵机呢?很简单,发送一条HTTP请求就可以了!

由于本人所使用的是🍎📱,那么可以优雅的采用Siri来控制开关灯。Siri配置如下:


💡其他方案如下:

  • 小爱同学等其他语音助手
  • 将开关灯的HTTP请求保存为书签放在手机桌面